expect "\r\n." send "r credir\r"; continue
expect -ri "directory:" send "[10,6,MCS10]\r"; continue
expect -ri "directory:"  at %TAPE% -r tapes/AP-D471B-SB_1978.tap; send "\3" ; continue
expect "\r\n." send "ASSIGN MTA0 BACKUP\r"; continue
expect "\r\n." send "SET DENS MTA0 800\r"; continue
expect "\r\n." send "R BACKUP\r"; continue
expect "\r\n/" send -t after=50000 "TAPE MTA0\r"; continue
expect "\r\n/" send "DEN 800\r"; continue
expect "\r\n/" send "FILES\r"; continue
expect "\r\n/" send "INTER\r"; continue
expect "\r\n/" send "RESTORE DSKB:[10,6,MCS10]*.*=*.*\r"; continue
expect "\r\n/" send "EXIT\r"; continue
expect "\r\n." send "R SETSRC\r"; continue
expect "\r\n*" send "CP [10,6,MCS10]\r"; continue
expect "\r\n*" send "\3"; continue
; Clean up files
expect "\r\n." send "DEL BLIS10.*\r"; continue
expect "\r\n." send "TECO MGNMAC.BLI\r"; continue
expect "\r\n*" send "SNC=\33\060LKEX\33\33"; continue
expect "\r\n." send "TECO MGNUTL.BLI\r"; continue
expect "\r\n*" send "NNOTE;\33\060LK\33\33"; continue
expect "\r\n*" send "NNOTE;\33\060LK\33\33"; continue
expect "\r\n*" send "NNOTE <\33\060LS)\33KEX\33\33"; continue
expect "\r\n." send "TECO MGNTRM.BLI\r"; continue
expect "\r\n*" send "NNOTE;\33\060LKEX\33\33"; continue
expect "\r\n." send "TECO MGNPT.BLI\r"; continue
expect "\r\n*" send "NNOTE;\33\060LKEX\33\33"; continue
expect "\r\n." send "TECO MGNTRE.BLI\r"; continue
expect "\r\n*" send "NNOTE -\33\060LKEX\33\33"; continue
expect "\r\n." send "TECO MGNMS2.BLI\r"; continue
expect "\r\n*" send "NNOTE -\33\060LK\33\33"; continue
expect "\r\n*" send "NHISTNEWMAX\33-10C4DSOWN \33\064DEX\33\33"; continue
expect "\r\n." send "TECO MGNMPP.BLI\r"; continue
expect "\r\n*" send "NNOTE -\33\060LK\33\33"; continue
expect "\r\n*" send "NNOTE -\33\060LKEX\33\33"; continue
expect "\r\n." send "TECO MGNPRG.BLI\r"; continue
expect "\r\n*" send "NNOTE -\33\060LKEX\33\33"; continue
expect "\r\n." send "TECO MCSREP.BLI\r"; continue
expect "\r\n*" send "NNOTE THAT\33\060LKEX\33\33"; continue
expect "\r\n." send "TECO GO.BLI\r"; continue
expect "\r\n*" send "NNOTE THAT\33\060LKEX\33\33"; continue
expect "\r\n." send "DEL *.BAK\r"; continue
; Rebuild MCS
expect "\r\n." send "COMPILE/COMPILE @MCSNBC\r"; continue
expect "\r\n." send "COMPILE/COMPILE INTERM.MAC,LCM.MAC,LCMIPC.MAC,KERNEL.MAC\r"; continue
expect "\r\n." send "R PIP\r"; continue
expect "\r\n*" send "MCS.REL=KERNEL.REL,CMDPRO.REL,MCSOPR.REL,RECVM.REL,DEVSER.REL,MISCMD.REL,SENDM.REL,DISPAK.REL,MSGIN.REL,UTIL.REL,MCSONC.REL,MSGOUT.REL,SON.REL,SOFF.REL,DMR.REL,DCR.REL,ERR.REL\r"; continue
expect "\r\n*" send "\3"; continue
expect "\r\n." send "DELETE KERNEL.UNV,INTERM.REL,INTERM.UNV\r"; continue
expect "\r\n." send "COMPILE/COMPILE @GENNBC\r"; continue
expect "\r\n." send "COMPILE/COMPILE MCSS.MAC\r"; continue
expect "\r\n." send "COMPILE/COMPILE @REPNBC\r"; continue
