expect "\r\n." send "r credir\r"; continue
expect -ri "directory:" send "[10,6,GAL2]\r"; continue
expect -ri "directory:" at %TAPE% -r tapes/AP-D483B-SB_1978.tap; send "\3" ; continue
expect "\r\n." send "ASSIGN MTA0 BACKUP\r"; continue
expect "\r\n." send "SET DENS MTA0 800\r"; continue
expect "\r\n." send "R BACKUP\r"; continue
expect "\r\n/" send -t after=50000 "TAPE MTA0\r"; continue
expect "\r\n/" send "DEN 800\r"; continue
expect "\r\n/" send "FILES\r"; continue
expect "\r\n/" send "INTER\r"; continue
expect "\r\n/" send "RESTORE DSKB:[10,6,GAL2]*.*=*.*\r"; continue
expect "\r\n/" send "EXIT\r"; continue
expect "\r\n." send "R SETSRC\r"; continue
expect "\r\n*" send "CP [10,6,GAL2]\r"; continue
expect "\r\n*" send "\3"; continue
expect "\r\n." send "DEL CREF.EXE,GLOB.EXE,HELPER.REL,LNK???.EXE,MACRO.EXE\r"; continue
expect "\r\n." send "DEL UUOSYM.UNV,WILD.REL,SCAN.REL,LINK.EXE\r"; continue
; Fix bug in sprint.
expect "\r\n." send "TECO SPRINT.MAC\r"; continue
expect "\r\n*" send "NMAKPTH:	\033KIMOVE	P1,[RIBCNT,,RIBCNT+1]\r	SETZM RIBCNT\r	BLT	P1,RIBCNT\r\033EX\033\033"; continue;
; Fix bug in Quasar.
expect "\r\n." send "TECO QSRT10.MAC\r"; continue
expect "\r\n*" send "NI$VSTR:\033\065LSCAI\033DIN\033SDCT\033\062DIDS\033EX\033\033"; continue
; Fix bug in Lptspl.
expect "\r\n." send "TECO LPTSPL.MAC\r"; continue
expect "\r\n*" send "NFILLB:\033\063KI    IN      DSK,\r\033EX\033\033"; continue
expect "\r\n." send "RUN GALGEN\r"; continue
expect "SHORT OR LONG DIALOG?" send "LONG\r"; continue
expect "OUTPUT FILE IS GALCNF.MAC (Y,N)<Y>:" send "\r"; continue
expect "TOPS10 or TOPS20?(10,20)<10>:" send "\r"; continue
expect "HOW MANY CPUS?(1-5)<1>:" send "\r"; continue
expect "SERIAL # OF CPU0(.GE. 513)<>:" send "514\r"; continue
expect "DO YOU WANT REDUNDANT MASTER QUEUE?(Y,N)<Y>:" send "\r"; continue
expect "FILE-STRUCTURE TO CONTAIN MASTER QUEUE ()<>:" send "DSKB\r"; continue
expect "DEFAULT RUNTIME LIMIT IN SECS (5-9999)<300>:" send "\r"; continue
expect "LPT OUTPUT IN PAGES (5-9999)<200>:" send "\r"; continue
expect "PTP OUTPUT IN FEET (5-9999)<10>:" send "\r"; continue
expect "CDP OUTPUT IN CARDS (5-9999)<100>:" send "\r";continue
expect "PLT OUTPUT IN MINS (5-9999)<10>:" send "\r"; continue
expect "DO YOU WANT TO ENFORCE CORE LIMITS?(Y,N)<N>:" send "\r"; continue
expect "DEFAULT PRIORITY FOR ALL REQUESTS (1-63)<10>:" send "\r"; continue
expect "FACTOR FOR LPT REQUESTS (-100 TO 100)<-2>:" send "\r"; continue
expect "FOR PTP REQUESTS (-100 TO 100)<10>:" send "\r"; continue
expect "FOR CDP REQUESTS (-100 TO 100)<30>:" send "\r"; continue
expect "FOR PLT REQUESTS (-100 TO 100)<2>:" send "\r"; continue
expect "WHAT IS THE BIAS TO BE ADDED IN (1,500)<50>:" send "\r"; continue
expect "DO YOU WANT REQUESTS SPLIT BY STRUCTURE? (Y,N)<Y>:" send "\r"; continue
expect "WHAT IS THE NAME OF STANDARD FORMS (6 CHARS)<NORMAL>:" send "\r"; continue
expect "NUMBER OF CHARACTERS IN A UNIQUE FORMS NAME (1-6)<4>:" send "\r"; continue
expect "NUMBER OF UNIQUE FORM TYPES CONSIDERED DURING SCHEDULING (1-20)<5>:" send "\r"; continue
expect "THRESHOLD FOR AUTOMATIC FORMS CHANGE (1-1000)<100>:" send "\r"; continue
expect "TO STOP SCHEDULING AUTOMATIC FORMS CHANGES (1,120)<20>:" send "\r"; continue
expect "MAXIMUM NUMBER OF CONCURRENT BATCH JOBS (1-127)<14>:" send "\r"; continue
expect "NUMBER OF MINUTES BETWEEN CHECKPOINTS (1-20)<3>:" send "\r"; continue
expect "\r\n." send "R MACRO\r"; continue
expect "\r\n*" send "SBSMAC(P)=SBSMAC\r"; continue
expect "\r\n*" send "SBSCOM(P)=SBSCOM\r"; continue
expect "\r\n*" send "GALCNF(P)=GALCNF\r"; continue
expect "\r\n*" send "QSRMAC(P)=QSRMAC\r"; continue
expect "\r\n*" send "QUASAR(P)=QUASAR\r"; continue
expect "\r\n*" send "QSRQUE(P)=QSRQUE\r"; continue
expect "\r\n*" send "QSRT10(P)=QSRT10\r"; continue
expect "\r\n*" send "QSRIPC(P)=QSRIPC\r"; continue
expect "\r\n*" send "QSRMEM(P)=QSRMEM\r"; continue
expect "\r\n*" send "QSRFSS(P)=QSRFSS\r"; continue
expect "\r\n*" send "QSRSCH(P)=QSRSCH\r"; continue
expect "\r\n*" send "QSRADM(P)=QSRADM\r"; continue
expect "\r\n*" send "CSPQSR(P)=CSPQSR\r"; continue
expect "\r\n*" send "CSPMEM(P)=CSPMEM\r"; continue
expect "\r\n*" send "BATCON=BATCON\r"; continue
expect "\r\n*" send "LPTSPL=LPTSPL\r"; continue
expect "\r\n*" send "SPROUT=SPROUT\r"; continue
expect "\r\n*" send "LOGOUT=LOGOUT\r"; continue
expect "\r\n*" send "QMANGR=QMANGR\r"; continue
expect "\r\n*" send "SPRINT=SPRINT\r"; continue
expect "\r\n*" send "QUENCH=QUENCH\r"; continue
expect "\r\n*" send "\3"; continue
;expect "\r\n." send "R GLOB\r"; continue
;expect "\r\n*" send "=QSRGLB=QUASAR,QSRQUE,QSRT10,QSRIPC,QSRMEM,QSRFSS,QSRSCH,QSRADM\033"; continue
expect "\r\n." send "R LINK\r"; continue
expect "\r\n*" send "TTY:/LOG /LOGL:0 /HASHSIZE:10000 /CORE:50P\r"; continue
expect "\r\n*" send "QUASAR/GO\r"; continue
expect "\r\n." send "NSAVE QUASAR\r"; continue
expect "\r\n." send "VERSION\r"; continue
expect "\r\n." send "R LINK\r"; continue
expect "\r\n*" send "TTY:/LOG /LOGL:0\r"; continue
expect "\r\n*" send "BATCON/GO\r"; continue
expect "\r\n." send "NSSAVE BATCON\r"; continue
expect "\r\n." send "VERSION\r"; continue
expect "\r\n." send "R LINK\r"; continue
expect "\r\n*" send "TTY:/LOG /LOGL:0\r"; continue
expect "\r\n*" send "LPTSPL/GO\r"; continue
expect "\r\n." send "NSSAVE LPTSPL\r"; continue
expect "\r\n." send "VERSION\r"; continue
expect "\r\n." send "R LINK\r"; continue
expect "\r\n*" send "TTY:/LOG /LOGL:0\r"; continue
expect "\r\n*" send "SPROUT/GO\r"; continue
expect "\r\n." send "NSSAVE SPROUT\r"; continue
expect "\r\n." send "VERSION\r"; continue
expect "\r\n." send "R LINK\r"; continue
expect "\r\n*" send "TTY:/LOG /LOGL:0\r"; continue
expect "\r\n*" send "LOGOUT/GO\r"; continue
expect "\r\n." send "NSSAVE LOGOUT\r"; continue
expect "\r\n." send "VERSION\r"; continue
expect "\r\n." send "R LINK\r"; continue
expect "\r\n*" send "TTY:/LOG /LOGL:0\r"; continue
expect "\r\n*" send "QMANGR/GO\r"; continue
expect "\r\n." send "NSSAVE QMANGR\r"; continue
expect "\r\n." send "VERSION\r"; continue
expect "\r\n." send "R LINK\r"; continue
expect "\r\n*" send "TTY:/LOG /LOGL:0\r"; continue
expect "\r\n*" send "QMANGR,QUENCH/GO\r"; continue
expect "\r\n." send "NSSAVE QUEUE\r"; continue
expect "\r\n." send "VERSION\r"; continue
expect "\r\n." send "R LINK\r"; continue
expect "\r\n*" send "TTY:/LOG /LOGL:0\r"; continue
expect "\r\n*" send "QMANGR,REL:HELPER,SPRINT/G\r"; continue
expect "\r\n." send "NSSAVE SPRINT\r"; continue
expect "\r\n." send "VERSION\r"; continue
